homogenization_mech_isostrain.f90

Go to the documentation of this file.

# 1 "/home/damask_user/GitLabCI_Pipeline_4301/DAMASK/src/homogenization_mech_isostrain.f90"
# 1 "<built-in>"
# 1 "<command-line>"
# 1 "/home/damask_user/GitLabCI_Pipeline_4301/DAMASK/src/homogenization_mech_isostrain.f90"
!--------------------------------------------------------------------------------------------------
!--------------------------------------------------------------------------------------------------
submodule(homogenization) homogenization_mech_isostrain
 
  enum, bind(c); enumerator :: &
    parallel_id, &
    average_id
  end enum
 
  type :: tparameters                                                                               
    integer :: &
      Nconstituents
    integer(kind(average_ID)) :: &
      mapping
  end type
 
  type(tParameters), dimension(:), allocatable :: param
  
 
contains
 
!--------------------------------------------------------------------------------------------------
!--------------------------------------------------------------------------------------------------
module subroutine mech_isostrain_init
 
  integer :: &
    Ninstance, &
    h, &
    NofMyHomog
  character(len=pStringLen) :: &
    tag  = ''
 
  write(6,'(/,a)')   ' <<<+-  homogenization_'//homogenization_isostrain_label//' init  -+>>>'
 
  ninstance = count(homogenization_type == homogenization_isostrain_id)
  if (iand(debug_level(debug_homogenization),debug_levelbasic) /= 0) &
    write(6,'(a16,1x,i5,/)') '# instances:',ninstance
 
  allocate(param(ninstance))                                                                        ! one container of parameters per instance
 
  do h = 1, size(homogenization_type)
    if (homogenization_type(h) /= homogenization_isostrain_id) cycle
    
    associate(prm => param(homogenization_typeinstance(h)),&
              config => config_homogenization(h))
   
    prm%Nconstituents = config_homogenization(h)%getInt('nconstituents')
    tag = 'sum'
    select case(trim(config%getString('mapping',defaultval = tag)))
      case ('sum')
        prm%mapping = parallel_id
      case ('avg')
        prm%mapping = average_id
      case default
        call io_error(211,ext_msg=trim(tag)//' ('//homogenization_isostrain_label//')')
    end select
 
    nofmyhomog = count(material_homogenizationat == h)
    homogstate(h)%sizeState       = 0
    allocate(homogstate(h)%state0   (0,nofmyhomog))
    allocate(homogstate(h)%subState0(0,nofmyhomog))
    allocate(homogstate(h)%state    (0,nofmyhomog))
    
    end associate
 
  enddo
 
end subroutine mech_isostrain_init
 
 
!--------------------------------------------------------------------------------------------------
!--------------------------------------------------------------------------------------------------
module subroutine mech_isostrain_partitiondeformation(f,avgf)
  
  real(pReal),   dimension (:,:,:), intent(out) :: F
  
  real(pReal),   dimension (3,3),   intent(in)  :: avgF
 
  f = spread(avgf,3,size(f,3))
 
end subroutine mech_isostrain_partitiondeformation
 
 
!--------------------------------------------------------------------------------------------------
!--------------------------------------------------------------------------------------------------
module subroutine mech_isostrain_averagestressanditstangent(avgp,davgpdavgf,p,dpdf,instance)
   
  real(pReal),   dimension (3,3),       intent(out) :: avgP
  real(pReal),   dimension (3,3,3,3),   intent(out) :: dAvgPdAvgF
 
  real(pReal),   dimension (:,:,:),     intent(in)  :: P
  real(pReal),   dimension (:,:,:,:,:), intent(in)  :: dPdF
  integer,                              intent(in)  :: instance 
   
  associate(prm => param(instance))
  
  select case (prm%mapping)
    case (parallel_id)
      avgp       = sum(p,3)
      davgpdavgf = sum(dpdf,5)
    case (average_id)
      avgp       = sum(p,3)   /real(prm%Nconstituents,preal)
      davgpdavgf = sum(dpdf,5)/real(prm%Nconstituents,preal)
  end select
  
  end associate
 
end subroutine mech_isostrain_averagestressanditstangent
 
end submodule homogenization_mech_isostrain